EBNF 中此函数的语法为：

CollectionFindFunction
  ::= '.find(' SearchConditionStr? ')' ( '.fields(' ProjectedDocumentExprStr ')' )?
      ( '.groupBy(' SearchExprStrList ')' )? ( '.having(' SearchConditionStr ')' )?
      ( '.sort(' SortExprStrList ')' )? ( '.limit(' NumberOfRows ')' ( '.offset(' NumberOfRows ')' )? )?
      ( '.lockExclusive(' LockContention ')' | '.lockShared(' LockContention ')' )? 
      ( '.bind(' PlaceholderValues ')' )*
      ( '.execute()' )?

图 11.9 CollectionFindFunction

EBNF 中显示的此函数的语法是：

CollectionModifyFunction
  ::= '.modify(' SearchConditionStr ')'
      ( '.set(' DocPath ',' ExprOrLiteral ')' |
        '.unset(' DocPath ( ',' DocPath )* ')' |
        '.arrayInsert(' DocPath ',' ExprOrLiteral ')' |
        '.arrayAppend(' DocPath ',' ExprOrLiteral ')' |
        '.patch(' DocumentOrJSON ')'
      )+
      ( '.sort(' SortExprStrList ')' )? ( '.limit(' NumberOfRows ')' )?
      ( '.bind(' PlaceholderValues ')' )*
      ( '.execute()' )?

图 11.10 CollectionModifyFunction

EBNF 中显示的此函数的语法是：

CollectionAddFunction
    ::= ( '.add(' ( DocumentOrJSON | '[' DocumentOrJSON ( ',' DocumentOrJSON )* ']' )? ')' )+
        ( '.execute()' )?

图 11.11 CollectionAddFunction

EBNF 中显示的此函数的语法是：

CollectionRemoveFunction
    ::= '.remove(' SearchConditionStr ')'
        ( '.sort(' SortExprStrList ')' )? ( '.limit(' NumberOfRows ')' )?
        ( '.bind(' PlaceholderValues ')' )*
        ( '.execute()' )?

图 11.12 CollectionRemoveFunction