11.7 其他 EBNF 定义_X DevAPI 用户指南

X DevAPI 用户指南 / 第 11 章 CRUD EBNF 定义 / 11.7 其他 EBNF 定义

11.7 其他 EBNF 定义

搜索条件Str

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
SearchConditionStr
  ::= '"' Expression '"'

图 11.24 SearchConditionStr

搜索表达式列表

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
SearchExprStrList
  ::= '[' '"' Expression '"' ( ',' '"' Expression '"' )* ']'

图 11.25 SearchExprStrList

ProjectedDocumentExprStr

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
ProjectedDocumentExprStr
  ::= ProjectedSearchExprStrList | 'expr("' JSONDocumentExpression '")'

图 11.26 ProjectedDocumentExprStr

ProjectedSearchExprStrList

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
ProjectedSearchExprStrList
  ::= '[' '"' Expression ( 'AS' Alias )? '"' ( ',' '"' Expression ( 'AS' Alias )? '"' )* ']'

图 11.27 ProjectedSearchExprStrList

排序表达式列表

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
SortExprStrList
  ::= '[' '"' Expression ( 'ASC' | 'DESC' )? '"' ( ',' '"' Expression ( 'ASC' | 'DESC' )? '"' )* ']'

图 11.28 SortExprStrList

表达式或字面量

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
ExprOrLiteral
  ::= 'expr("' Expression '")' | Literal

图 11.29 ExprOrLiteral

ExprOrLiterals

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
ExprOrLiterals
  ::= ExprOrLiteral ( ',' ExprOrLiteral )*

图 11.30 ExprOrLiterals

ExprOrLiteralOrOperand

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
ExprOrLiteralOrOperand
  ::= ExprOrLiteral

图 11.31 ExprOrLiteralOrOperand

占位符值

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
PlaceholderValues
  ::= '{' PlaceholderName ':' ( ExprOrLiteral ) '}'

图 11.32 占位符值

占位符名称

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
PlaceholderName
  ::= NamedPlaceholderNotQuestionmarkNotNumbered

图 11.33 占位符名称

文档路径

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
DocPath
  ::= ( '[*]' | ( '[' Index ']' ) | '.*' | ( '.' StringLiteral ) | '**' )+

图 11.34 文档路径

文字

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
Literal
  ::= '"' StringLiteral '"' | Number | true | false | Document

图 11.35 文字

表达

Press CTRL+C to copy
 
Expression
  ::= Literal
   | DocPath
   | TableField
   | FunctionName '(' Expression ( ',' Expression )* ')'
   | ':' PlaceholderName
   | Expression Operator Expression
   | JSONExpression

图 11.36 表达式

文档

期望 JSON 文档的 API 调用允许使用多种数据类型来描述文档。根据 X DevAPI 实现和语言，可以使用以下任何数据类型：

细绳
原生 JSON
JSON 等效语法
数据库文档
生成的文档类

X DevAPI 的所有实现都允许通过特殊的 DbDoc 类型和字符串来表达文档。

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
Document
  ::= JSONDocument | JSONEquivalentDocument | DbDoc | GeneratedDocumentClasses

图 11.37 文档

JSON表达式

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
JSONExpression
  ::= JSONDocumentExpression | '[' Expression ( ',' Expression )* ']'

图 11.38 JSONExpression

JSON文档表达式

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
JSONDocumentExpression
  ::= '{' StringLiteral ':' JSONExpression (',' StringLiteral ':' JSONExpression)* '}'

图 11.39 JSONDocumentExpression

函数名

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
FunctionName
  ::= StringLiteral | StringLiteral '.' StringLiteral

图 11.40 函数名

文档或JSON

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
DocumentOrJSON
  ::= Document | 'expr("' JSONDocumentExpression '")'

图 11.41 DocumentOrJSON

表字段

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
TableField
  ::= ( StringLiteral '.' )? ( StringLiteral '.' )? StringLiteral ( '@' DocPath )?

图 11.42 表字段

表字段

EBNF 中显示的此函数的语法是：

Press CTRL+C to copy
 
TableFields
  ::= ( '[' TableField ( ',' TableField )* ']' )

图 11.43 表字段